A SimpleDataField with WebRequest

Here's some source code and instructions. I tested this in the simulator, but not on a real device.

1) In VS Code, use the command palette to create a new monkey C project. CTRL/CMD-SHIFT-P > "Monkey C: New Project"

- Project name: WaterTempDF

- Type: Data Field (Simple)

- Minimum API level 3.0.0

(Background services require 2.3.0. but this code uses HTTP_RESPONSE_CONTENT_TYPE_TEXT_PLAIN (*) which is only present in 3.0.0 and higher)

(*) Technically the service you're talking to is returning valid JSON (a number) but unfortunately Connect IQ requires JSON web responses to be wrapped in an object. So in this case, we have to tell Connect IQ the response is plain text.

2) Use Command Palette > "Monkey C: Edit Products" to add the product of your choice. (I tested with fr955)

3) Use Command Palette > "Monkey C: Edit Permissions" to add the Background and Communications permissions

4) Replace WaterTempDFApp.mc with the following code:

import Toybox.Application;
import Toybox.Lang;
import Toybox.WatchUi;
import Toybox.Background;
import Toybox.Communications;
import Toybox.System;

(:background) class WaterTempDFApp extends Application.AppBase {
    var view as WaterTempDFView or Null;

    function initialize() {
        AppBase.initialize();
    }

    function onStart(state as Dictionary?) as Void {
    }

    function onStop(state as Dictionary?) as Void {
    }

    // Return the initial view of your application here
    function getInitialView() as Array<Views or InputDelegates>? {
        if (Background.getTemporalEventRegisteredTime() != null) {
            Background.registerForTemporalEvent(new Time.Duration(5 * 60));
        }
        view = new WaterTempDFView();
        return [view] as Array<Views or InputDelegates>;
    }

    public function getServiceDelegate() as Array<System.ServiceDelegate> {
        return [new AppServiceDelegate()];
    }

    public function onBackgroundData(data as Application.PersistableType) as Void {
        if (data == null || data instanceof Lang.Float) {
            if (view != null) {
                view.onTemperatureUpdated(data);
            }
        }
    }
}

function getApp() as WaterTempDFApp {
    return Application.getApp() as WaterTempDFApp;
}

(:background) class AppServiceDelegate extends System.ServiceDelegate {
    function initialize() {
        System.ServiceDelegate.initialize();
    }
    function onReceive(responseCode as Lang.Number, data as Lang.Dictioanry or Lang.String or Null) as Void {
        System.println("onReceive: response code: " + responseCode + ", data: " + data);
        if (responseCode == 200) {
            if (data instanceof Lang.String) {
                // Convert string to float. If conversion fails, null will be returned
                var dataAsFloat = data.toFloat();
                Background.exit(dataAsFloat);
            }
        }
        Background.exit(null);
    }

    public function onTemporalEvent() as Void {
        Communications.makeWebRequest(
            "https://aareguru.existenz.ch/v2018/current",
            {
                "city" => "thun",
                "version" => "1.042",
                "values" => "aare.temperature"
            },
            {
                :method => Communications.HTTP_REQUEST_METHOD_GET,
                :responseType  => Communications.HTTP_RESPONSE_CONTENT_TYPE_TEXT_PLAIN
            },
            method(:onReceive)
        );
    }
}

5) Replace WaterTempDFView.mc with the following code:

import Toybox.Activity;
import Toybox.Lang;
import Toybox.Time;
import Toybox.WatchUi;

class WaterTempDFView extends WatchUi.SimpleDataField {
    var lastTemperature = null as Float or Null;

    function initialize() {
        SimpleDataField.initialize();
        label = "Water Temp";
    }

    function compute(info as Activity.Info) as Numeric or Duration or String or Null {
        return lastTemperature;
    }

    function onTemperatureUpdated(newTemperature as Float or Null) as Void {
        System.println("onTemperatureUpdated: " + newTemperature);
        if (newTemperature != null) {
            lastTemperature = newTemperature;
        }
    }
}

There is obviously a typo in onReceive()'s signature: Lang.Dictioanry should be Lang.Dictionary. For whatever reason, the code still compiles (with the default type checking level). Unfortunately the forum won't allow me to edit the code :/. For the same reason, I can't fix the handful of errors that arise when strict type checking is enabled.

6) Build and run the app in the simulator by pressing F5. Trigger a background temporal event by opening the simulator app menu and selecting Simulation > Background Events > Event Type: Temporal Event

This is what I see in the sim: