makeWebRequest ResponseCode == 0 when it should be 4xx

using Toybox.Application as App;
using Toybox.Lang as Lang;
using Toybox.System as Sys;
using Toybox.WatchUi as Ui;
using Toybox.Graphics as Gfx;
using Toybox.Communications as Comm;

class XResponseDelegate
{
    hidden var _M_url;

    function initialize(url) {
        _M_url = url;
    }

    hidden var _M_callback;

    function makeWebRequest(url, params, options, callback) {
        _M_callback = callback;

        Comm.makeWebRequest(url, params, options, method(:onWebResponse));
    }

    function onWebResponse(code, data) {
        _M_callback.invoke(code, data, _M_url);
    }
}

class XBehaviorDelegate extends Ui.BehaviorDelegate
{
    hidden var _M_code;

    function initialize() {
        BehaviorDelegate.initialize();
    }

    function fetchResponse(code) {
        var url = Lang.format("localhost:8000/$1$", [ code ]);

        var params = {
        };

        var options = {
        };

        var delegate = new XResponseDelegate(url);
        delegate.makeWebRequest(url, params, options, method(:onWebResponse));
    }

    function onSelect() {

        if (_M_code == null) {
            _M_code = 100;
            fetchResponse(_M_code);
        }

        return true;
    }

    function onWebResponse(code, data, url) {
        Sys.println(Lang.format("$1$ returned $2$", [ url, code ]));

        if (_M_code < 599) {
            ++_M_code;
            fetchResponse(_M_code);
        }
        else {
            _M_code = null;
        }
    }
}

class XView extends Ui.View
{
    function initialize() {
        View.initialize();
    }

    function onUpdate(dc) {
        dc.setColor(Gfx.COLOR_WHITE, Gfx.COLOR_BLACK);
        dc.clear();
    }
}

class XApp extends App.AppBase
{
    function initialize() {
        AppBase.initialize();
    }

    function getInitialView() {
        return [ new XView(), new XBehaviorDelegate() ];
    }
}