makeWebRequest call crashes Garmin Connect Mobile

Assuming you're doing conversions on the device, I think you'd see some speedup if you did some server side processing on the data. You would need to write a web service of your own that accesses the data from the original source, converts the date-time values into timestamps and the measurements into actual floating-point values before forwarding the result back to the client. That would eliminate a lot of the storage cost on the device side when initially processing the response, and possibly reduce the conversion costs.

Additionally, it might help if you add a simple queuing mechanism for your requests. It might reduce parallelism (because the mobile phone can serve multiple requests simultaneously), but you'd get ordered responses and you could easily add support for user data being passed back with your response. Something like this...

using Toybox.Communications as Comm;
using Toybox.System as Sys;
using Toybox.Lang as Lang;
using Toybox.Time as Time;
using Toybox.Time.Gregorian as Gregorian;

class WebRequestManager
{
// internal implementation detail
class Request {
var url;
var params;
var options;
var callback;
var user_data;
var next;

function initialize(url, params, options, callback, user_data) {
self.url = url;
self.params = params;
self.options = options;
self.callback = callback;
self.user_data = user_data;
}

function makeWebRequest(callback) {
Comm.makeWebRequest(self.url, self.params, self.options, callback);
}

function onWebResponse(code, data) {
callback.invoke(code, data, self.user_data);
}
}


function initialize() {
}

hidden var queue_head;
hidden var queue_tail;

function makeWebRequest(url, params, options, callback, user_data) {
var request = new Request(url, params, options, callback, user_data);

// no queued requests
if (queue_head == null) {
// put our request at the front of the queue
queue_head = request;
queue_tail = request;

// and submit the request
request.makeWebRequest(self.method(:onWebResponse));
}

// put the new request at the end of the queue. it will execute when
// all of the previously queued requests complete
else {
queue_tail.next = request;
queue_tail = request;
}
}

function cancelAll() {
Comm.cancelAll();

// clear out our queue of requests
queue_head = null;
queue_tail = null;
}

function onWebResponse(code, data) {
// get handle to the top request
var request = queue_head;

// remove the top request
queue_head = request.next;
request.next = null;

if (queue_head == null) {
queue_tail = null;
}

// invoke the callback contained in the response
request.onWebResponse(code, data);

// submit another response if there are more
if (queue_head != null) {
queue_head.makeWebRequest(self.method(:onWebResponse));
}
}
}


Then you should be able to queue up your requests like this...

class MyBehaviorDelegate extends Ui.BehaviorDelegate
{
function initialize(manager) {
BehaviorDelegate.initialize();
_manager = manager;
}

// helper function formats a time for the web service request given a
// broken-down time Time.Info
hidden function format_time(info) {
return Lang.format("$1$$2$$3$ $4$:$5$", [
info.year.format("%04d"),
info.month.format("%02d"),
info.day.format("%02d"),
info.hour.format("%02d"),
info.min.format("%02d")
]);
}

function onSelect() {

var options = {
:method => Comm.HTTP_REQUEST_METHOD_GET,
:responseType => Comm.HTTP_RESPONSE_CONTENT_TYPE_JSON,
:headers => {
"Content-Type" => Comm.REQUEST_CONTENT_TYPE_JSON
}
};

// get samples for every 6 minutes
var off = new Time.Duration(360);

// starting now, and going for 60 minutes
var beg = Time.now();
var end = beg.add(new Time.Duration(3600));

var url = "tidesandcurrents.noaa.gov/.../datagetter";

for (var user_data = 0; beg.lessThan(end); beg = beg.add(off)) {

var beg_date = Gregorian.info(beg, Time.FORMAT_SHORT);
var end_date = Gregorian.info(end, Time.FORMAT_SHORT);

var params = {
"begin_date" => format_time(beg_date),
"end_date" => format_time(end_date),
"station" => "8454000",
"product" => "predictions",
"datum" => "mllw",
"units" => "english",
"time_zone" => "lst",
"application" => "web_services",
"format" => "json"
};

manager.makeWebRequest(url, options, params, self.method(:onWebResponse), user_data);

user_data += 1;
}

return true;
}

function onWebResponse(code, data, user_data) {
Sys.println(code);
Sys.println(user_data);
Sys.println(data);
}
}