Menu2 a lot of questions.

I think you make the mistake of using MenuInputDelegate instead of Menu2InputDelegate. Notice the 2 missing. So you have an incorrect inputdelegate, thus your code breaks. Be advised that with Menu2InputDelegate you get an Item object, where you first must get the id to get to the symbol.

Than some unsolicited advice.

I wouldn't build menu's in your delegates, just make it a class somewhere and than in the delegate call Ui.pushView(new YourMenu2Class(), new YourMenu2ClassDelegate()) it makes your code much more readable and modular. You can reuse your code much more easily.

While I use snake_case at $work I would advise you to use camelCase in MonkeyC projects. The whole MonkeyC universe uses that, so your code will look a lot more natural when using camelCase.

Many thanks for you answer and advice

now my teste4MenuDelegate.mc is like

import Toybox.Lang;
import Toybox.System;
import Toybox.WatchUi;

class teste4Menu2Delegate extends WatchUi.Menu2InputDelegate {

    function initialize() {
        Menu2InputDelegate.initialize();
    }

    function onSelect(item) {

        if (item.getId().equals("item_sail")) { 

            System.println("VELAS");

            //CREATE SUB MENU
            var menu_sub = new WatchUi.Menu2({:title=>"Sails Size"});

            menu_sub.addItem(new WatchUi.MenuItem("7.8",null,"sail1",null));
            menu_sub.addItem(new WatchUi.MenuItem("7.1", null,"sail2", null));
            menu_sub.addItem(new WatchUi.MenuItem("6", null,"sail3", null));

            WatchUi.pushView(menu_sub, new teste4Menu2Delegate(), WatchUi.SLIDE_IMMEDIATE);

            return true;

        } else if (item.getId().equals("sail1")) { System.println("you chose sail 7.8"); }

        return false;

    }


    /*
        function onMenuItem(item as Symbol) as Void {


        }
    */


}

and is running good :D the structure isn't the best, but I will improve :D I need to understand the "mechanic"

An IconMenuItem is just like a MenuItem, but it has an icon to the left or the right of the label. Let's say you want to add an icon to the "item_sail" MenuItem:

 var menu = new WatchUi.Menu2({:title => "Wind Surf"});
 var appIcon = WatchUi.loadResource(Rez.Drawables.LauncherIcon);

 menu.addItem(new WatchUi.IconMenuItem("Sails", null, "item_sail", appIcon, null));
 menu.addItem(new WatchUi.MenuItem("Boards", null, "item_board", null));

 WatchUi.pushView(menu, new teste4Menu2Delegate(), WatchUi.SLIDE_IMMEDIATE);

Hello. Thanks for your answer.

error:

Error: Unhandled Exception
Exception: UnexpectedTypeException: Unexpected icon type, expected Drawable
Stack: 
  - setIcon() at /Users/Shared/Garmin/prj/di/toolchain3/mbsimulator/submodules/technology/monkeybrains/virtual-machine/api/WatchUi.mb:3598 0x300037e7 
  - initialize() at /Users/Shared/Garmin/prj/di/toolchain3/mbsimulator/submodules/technology/monkeybrains/virtual-machine/api/WatchUi.mb:3581 0x30003764 
  - onMenu() at /Users/adinis/relogio_garmin/app/teste4/teste4/source/teste4Delegate.mc:26 0x1000033e 
  - handleEvent() at /Users/Shared/Garmin/prj/di/toolchain3/mbsimulator/submodules/technology/monkeybrains/virtual-machine/api/WatchUi.mb:1462 0x300026d6 

line 26:

 menu.addItem(new WatchUi.IconMenuItem("Sails", null, "item_sail", appIcon, null));

I don't need to set the icon's position ?? thanks!

Like the doc says, the default position is left. You only need to specify the position if you want it to be right.

As far as your exception goes, the doc says that the icon can be a Drawable or BitmapType (which includes BitmapResource), but passing in a resource doesn't seem to be working here. I tried it myself and got the same results. Not sure if that's a bug or not. (I've filed a bug report.)

If you create a Drawable class to draw the icon and pass it in, that works.

e.g.

        //...
        menu.addItem(
            new WatchUi.IconMenuItem(
                "Sails",
                null,
                "item_sail",
                new CustomIcon(Rez.Drawables.LauncherIcon),
                null
            )
        );
        // ...
    } // end of function
    // ...
} // end of class

class CustomIcon extends WatchUi.Drawable {
    var bitmapResource = null;
    public function initialize(resourceId) {
        Drawable.initialize({});
        bitmapResource = WatchUi.loadResource(resourceId);
    }

    public function draw(dc as Dc) as Void {
        dc.setColor(Graphics.COLOR_TRANSPARENT, Graphics.COLOR_TRANSPARENT);
        dc.clear();
        dc.drawBitmap(0, 0, bitmapResource);
    }
}

Have you looked at the menu2sample in the SDK?  It shows not only Icons (checkboxes and Toggles too), but also 'Custom" including Images.

Many Many thanks!! it's working :) thanks a lot!!

yes. I saw this:

https://developer.garmin.com/connect-iq/core-topics/native-controls/

and about doing a menu and icon "by coding" I didn't see... only with XML.

thanks!