How to enable an "always-on" mode for Venu/AMOLED

So after further investigation I think my design is actually working correctly! I think the problem is that when I place the watch on a table, it automatically shuts the screen fully off. I can't get it to work unless I'm wearing it. It must be using heart rate or something because I can also make it work by putting my thumb firmly over the heart rate sensor.

Hi, I'm looking at starting creating a watch face, would you be able to help share your code so I can see how to configure always on?

Here's the view for a really simple on.  If in High power, it displays the seconds.  If in low power, it moves the time around on a venu.

using Toybox.WatchUi;
using Toybox.Graphics as Gfx;
using Toybox.System as Sys;
using Toybox.Time.Gregorian as Calendar;

class AlwaysView extends WatchUi.WatchFace {

	var width, height;
	var timeF=Gfx.FONT_NUMBER_MEDIUM;
	var timeFH=0;
	var inLowPower=false;
	var canBurnIn=false;
	var upTop=true;
	
    function initialize() {
        WatchFace.initialize();
        //check if burn in protection needed
        var sSettings=Sys.getDeviceSettings();
        //first check if the setting is availe on the current device
        if(sSettings has :requiresBurnInProtection) {
        	//get the state of the setting      
        	canBurnIn=sSettings.requiresBurnInProtection;        	
        }        
    }

    // Load your resources here
    function onLayout(dc) {
		width=dc.getWidth();
		height=dc.getHeight();
		timeFH=dc.getFontHeight(timeF);
	}

    function onShow() {
    }

    function onUpdate(dc) {
   		dc.setColor(Gfx.COLOR_BLACK,Gfx.COLOR_BLACK);
   		dc.clear();
   		dc.setColor(Gfx.COLOR_WHITE,Gfx.COLOR_TRANSPARENT);

		//do the common date/time code
        var now = Time.now();
        var clockTime = Calendar.info(now, Time.FORMAT_MEDIUM);
        var hour=clockTime.hour;      
        if(!Sys.getDeviceSettings().is24Hour) {
			hour = hour % 12;
            hour = (hour == 0) ? 12 : hour;
        }        
        var timeString=hour+":"+clockTime.min.format("%02d");
        var dateString=clockTime.month+" "+clockTime.day;
        
        //setop for the display of the date and time
        var y=height/2;
		if(inLowPower) {
			if(canBurnIn) {
				//move things on the venu
				y=(upTop) ? height*.25 : height*.75;
				upTop=!upTop;
			}
		} else {
			//add seconds if not in low power (sleep) mode
			timeString=timeString+":"+clockTime.sec.format("%02d");
		}
		//actually display date and time
		dc.drawText(width/2,y,timeF,timeString,Gfx.TEXT_JUSTIFY_CENTER|Gfx.TEXT_JUSTIFY_VCENTER);
		dc.drawText(width/2,y+timeFH/2,Gfx.FONT_TINY,dateString,Gfx.TEXT_JUSTIFY_CENTER|Gfx.TEXT_JUSTIFY_VCENTER);
    }

    function onHide() {
    }
    
    function onExitSleep() {
        inLowPower=false;
    	WatchUi.requestUpdate(); 
    }

    function onEnterSleep() {
    	inLowPower=true;
    	WatchUi.requestUpdate(); 
    }
}

Thanks for posting. Mine is essentially the same thing. I also change fonts to a small/skinny font in low power mode, because you need to use <= 10% of the pixels, so having large fonts makes it hard to satisfy the always-on requirements. If you don't satisfy the requirements, the screen will just automatically turn off. So if you are seeing your screen turn off, try reducing the pixels in use, and make sure you are rotating the text enough so that you are not overlapping pixels. Also like I said, if you have a real device, you have to be actually wearing it otherwise the screen will shut off no matter what you do.

The fonts I use in the sample work fine.  You can see where you're at viewing the heatmap in the sim and doing the 24 hour simulation.  There are things you can do to be withing limits without moving things around.   in Simple Lean by way of app settings, you can see a method where the time doesn't move, but is dimmer (I vary what pixels are on)

With a real device, it uses OHR to see if you're wearing the watch.  If not the screen goes blank

Hello Jim, i just tried your example above and it does not work, screen always turn to black-blank...also my implementation works fine in 24-hour simulation but no success on the watch.

Any suggestions? Or does it only work after uploading in store?

Do you have always on enabled on the watch?  You also must be wearing the watch.  If there's no HR detected, it will blank.

Ok, i have tried to change it to always on, and back, after several times it started working! Thanks.

Based on jim_m_58's example, you need to shift the hands center point every second to prevent a single pixel from being lit on the same position for more than 3 seconds (burn-in protection). However, I know this is hard to achieve on analog hands as I've been trying this for a few days now and still couldn't get it working. I started to try shifting the centre point a bit to the sides as well (together with up/down) and got to a point where I can get the analog hands for 5 minutes on the heat map simulator until a couple of pixels reach the burn-in limit (instead of most of the hour hand at 3 minutes). 

 I'll give it a try a bit more with different options, but in case I can't get it working, the solution would be to use some kind of interlacing on the drawPolygon, but no clue yet on how to do it. Any ideas, jim_m_58 ?