[CIQBUG] saving application properties does not appear to work as expected

The below watch-app code demonstrates a problem with serializing application properties from within a function called by App.onStop(). Start the application and you should see a 1 displayed. If you press the up/down buttons or tap/swipe the screen, you should see the value change. When you exit the application, the value should be saved, and it should be restored on application startup.

I've tested on a vivoactive and a fr920xt, and I see the same behavior on both. I had previously been able to reproduce on the simulator, but that seems to be working now. If I enable the code to save the property after every press, tap, or swipe, the value is saved, but this should not be necessary.

using Toybox.Application as App;
using Toybox.Graphics as Gfx;
using Toybox.WatchUi as Ui;
using Toybox.System as Sys;

class TestModel
{
hidden var value;

function initialize() {
// Sys.println("Model.initialize");
value = 1;
}

function serialize(app) {
// Sys.println("Model.serialize");
app.setProperty("value", value);
}

function deserialize(app) {
// Sys.println("Model.deserialize");
var val = app.getProperty("value");
if (val != null) {
value = val;
}
}

function incrementValue() {
// Sys.println("Model.incrementValue");
value += 1;
//serialize(App.getApp());
}

function decrementValue() {
// Sys.println("Model.decrementValue");
value -= 1;
//serialize(App.getApp());
}

function getValue() {
// Sys.println("Model.getValue");
return value;
}
}

class TestController extends Ui.InputDelegate
{
hidden var model;

function initialize(model) {
// Sys.println("Controller.initialize");
self.model = model;
}

function onKey(evt) {
// Sys.println("Controller.onKey");
var key = evt.getKey();
if (key == Ui.KEY_UP) {
model.incrementValue();
}
else if (key == Ui.KEY_DOWN) {
model.decrementValue();
}
else {
return false;
}

Ui.requestUpdate();
return true;
}

function onTap(evt) {
// Sys.println("Controller.onTap");
model.incrementValue();
Ui.requestUpdate();
}

function onSwipe(evt) {
// Sys.println("Controller.onSwipe");
var dir = evt.getDirection();
if (dir == Ui.SWIPE_UP || dir == Ui.SWIPE_RIGHT) {
model.incrementValue();
}
else if (dir == Ui.SWIPE_DOWN || dir == Ui.SWIPE_LEFT) {
model.decrementValue();
}
else {
return false;
}

Ui.requestUpdate();
return true;
}

}

class TestView extends Ui.View
{
hidden var model;

function initialize(model) {
// Sys.println("View.initialize");
self.model = model;
}

function onUpdate(dc) {
// Sys.println("View.onUpdate");

dc.setColor(Gfx.COLOR_WHITE, Gfx.COLOR_BLACK);
dc.clear();

var cx = dc.getWidth() / 2;
var cy = dc.getHeight() / 2;

dc.drawText(cx, cy, Gfx.FONT_NUMBER_HOT, model.getValue().format("%d"),
Gfx.TEXT_JUSTIFY_CENTER | Gfx.TEXT_JUSTIFY_VCENTER);
}
}

class TestApp extends App.AppBase
{
hidden var model;
hidden var view;
hidden var controller;

function initialize() {
// Sys.println("App.initialize");
model = new TestModel();
view = new TestView(model);
controller = new TestController(model);
}

function onStart(state) {
// Sys.println("App.onStart");
model.deserialize(self);
}

function onStop(state) {
// Sys.println("App.onStop");
model.serialize(self);
}

function getInitialView() {
// Sys.println("App.getInitialView");
return [ view, controller ];
}

}